Using while loops within data_events

PROGRAM_NAME='Denon TU-604CI'
(* 
    DENON TU-604CI MULTIPLE TUNER
    -----------------------------
    Programmer: Kim Burgess
    Notes:
	Requires straight-through RS232 cable.
	Requires 'Option Setup > RS-232C Power' set to "ON" on the device.
	Once defined in the DEV array TUNERS[], each device can be controlled by passing their array
	index to the methods. Alternatively all devices in the system can be send a command by passing
	tuner_num 0.
	
    Communication format:
	9600bps,8,N,1,1
	135 bytes (max) data length
	
    Methods:
	TU_POWER(tuner_num,action)	 	Change or query the power state of the whole unit
	TU_SLOT_POWER(tuner_num,slot,action)	Change or query the power state of a specific slot
*)

DEFINE_CONSTANT
// Power commands
POFF=0
PON=1
STAT=100
(***********************************************************)
DEFINE_TYPE
STRUCTURE ANALOG_INFO
{
    INTEGER FREQUENCY
    INTEGER TUNER_BAND
    INTEGER MODE
    CHAR NAME[8]		// RDS PS
    CHAR PROGRAM_TYPE[8]	// RDS PTY
}
STRUCTURE DAB_INFO
{
    INTEGER CHAN
    INTEGER MODE
    CHAR NAME[8]
    CHAR LONG_NAME[16]
    CHAR ENSEMBLE_NAME[16]
    CHAR PROGRAM_TYPE[16]
    INTEGER FREQUENCY
    INTEGER MONO_STEREO
    INTEGER SIGNAL
}
STRUCTURE SLOT_INFO
{
    INTEGER POWER
    INTEGER TYPE
    INTEGER PRESET
    ANALOG_INFO ANALOG_STATE
    DAB_INFO DAB_STATE
}
STRUCTURE DENON_INFO
{
    CHAR RESPONSE_BUFF[255]
    INTEGER POWER
    INTEGER SOURCE
    SLOT_INFO SLOT_STATE[6]
}
(***********************************************************)
DEFINE_VARIABLE
DEV TUNERS[]={TUNER}
DENON_INFO TUNER_STATE[LENGTH_ARRAY(TUNERS)]
VOLATILE INTEGER TUNER_NUM
VOLATILE INTEGER SLOT_NUM
VOLATILE INTEGER COUNT
(***********************************************************)
DEFINE_CALL 'TU_POWER'(INTEGER TUNER_NUM, INTEGER ACTION)
STACK_VAR CHAR DV_COMMAND[7]
{
    SWITCH(ACTION)
    {
	CASE PON:{DV_COMMAND='ON'}
	CASE POFF:{DV_COMMAND='STANDBY'}
	CASE STAT:{DV_COMMAND='?'}
    }
    IF(TUNER_NUM>0)
	SEND_STRING TUNERS[TUNER_NUM],"'PW',DV_COMMAND,$0D"
    ELSE
	SEND_STRING TUNERS,"'PW',DV_COMMAND,$0D"
}
DEFINE_CALL 'TU_SLOT_POWER'(INTEGER TUNER_NUM, INTEGER SLOT_NUM, INTEGER ACTION)
STACK_VAR CHAR DV_COMMAND[7]
{
    SWITCH(ACTION)
    {
	CASE PON:{DV_COMMAND='ON'}
	CASE POFF:{DV_COMMAND='STANDBY'}
	CASE STAT:{DV_COMMAND='?'}
    }
    IF(TUNER_NUM>0)
	SEND_STRING TUNERS[TUNER_NUM],"'PWS',ITOA(SLOT_NUM),DV_COMMAND,$0D"
    ELSE
	SEND_STRING TUNERS,"'PWS',ITOA(SLOT_NUM),DV_COMMAND,$0D"
}
DEFINE_CALL 'PROCESS_RESPONSE'(INTEGER TUNER_NUM)
LOCAL_VAR CHAR RESPONSE[32]
{
    RESPONSE=REMOVE_STRING(TUNER_STATE[TUNER_NUM].RESPONSE_BUFF,"$0D",1)
    SELECT
    {
	ACTIVE(FIND_STRING(RESPONSE,'PWON',1)):{TUNER_STATE[TUNER_NUM].POWER=PON}
	ACTIVE(FIND_STRING(RESPONSE,'PWSTANDBY',1)):{TUNER_STATE[TUNER_NUM].POWER=POFF}
	ACTIVE(MID_STRING(RESPONSE,3,1)='S'):	// String was a slot state return
	{
	    SLOT_NUM=ATOI(MID_STRING(RESPONSE,4,1))	// Grab the slot number from the received string
	    SELECT
	    {
		ACTIVE(FIND_STRING(RESPONSE,'PW',1)):	// Slot power states
		{
		    SELECT
		    {
			ACTIVE(FIND_STRING(RESPONSE,'ON',5)):{TUNER_STATE[TUNER_NUM].SLOT_STATE[SLOT_NUM].POWER=PON}
			ACTIVE(FIND_STRING(RESPONSE,'STANDBY',5)):{TUNER_STATE[TUNER_NUM].SLOT_STATE[SLOT_NUM].POWER=POFF}
		    }
		}
	    }
	}
    }
}
(***********************************************************)
DEFINE_START

(***********************************************************)
DEFINE_EVENT
DATA_EVENT[TUNERS]
{
    ONLINE:	// Initialize coms and grab the state of the unit
    {
	TUNER_NUM=GET_LAST(TUNERS)
	SEND_COMMAND TUNERS[TUNER_NUM], 'SET BAUD 9600 N,8,1 485 DISABLE'
	CALL 'TU_POWER'(TUNER_NUM,STAT)
	CALL 'TU_SLOT_POWER'(TUNER_NUM,1,STAT)
    }
    STRING:	// Pass the received data into the units processing cue
    {
	TUNER_NUM=GET_LAST(TUNERS)
	TUNER_STATE[TUNER_NUM].RESPONSE_BUFF="TUNER_STATE[TUNER_NUM].RESPONSE_BUFF,DATA.TEXT"
    }
}
(***********************************************************)
DEFINE_PROGRAM
FOR(COUNT=1;COUNT<=LENGTH_ARRAY(TUNERS);COUNT++)	// Process any pending repsonse data for each unit in the system
{
    IF(LENGTH_STRING(TUNER_STATE[COUNT].RESPONSE_BUFF)>0)
	CALL 'PROCESS_RESPONSE'(COUNT)
}

a_riot42 wrote: »

I think your caps lock key is stuck on

I don't write code like that because I don't want a loop to continuously run in mainline when 99.99% of the time the buffer will be empty. Why not call your function directly from the string event once you have a full command string?
Paul

DEFINE_EVENT
DATA_EVENT[TUNERS]
{
    ONLINE:	// Initialize coms and grab the state of the unit
    {
	TUNER_NUM=GET_LAST(TUNERS)
	SEND_COMMAND TUNERS[TUNER_NUM], 'SET BAUD 9600 N,8,1 485 DISABLE'
	CALL 'TU_POWER'(TUNER_NUM,STAT)
	CALL 'TU_SLOT_POWER'(TUNER_NUM,ALL,STAT)
	CALL 'TU_SELECT_SOURCE'(TUNER_NUM,STAT)
    }
    STRING:	// Process the received data to update the units state info
    {
	TUNER_NUM=GET_LAST(TUNERS)
	WHILE(FIND_STRING(DATA.TEXT,"$0D",1))	// Occasionally multiple commands are recieved so make sure we break them up and process them all
	{
	    RESPONSE=REMOVE_STRING(DATA.TEXT,"$0D",1)			// Grab the front most received command
	    RESPONSE=LEFT_STRING(RESPONSE,LENGTH_STRING(RESPONSE)-1)	// Remove the trailing carridge return
	    SLOT_NUM=ATOI(MID_STRING(RESPONSE,4,1))			// Grab the slot number from the received string
	    SWITCH(LEFT_STRING(RESPONSE,2))
	    {
		CASE 'PW':	// Power states
		{
		    SELECT
		    {
			ACTIVE(RESPONSE='PWON'):{TUNER_STATE[TUNER_NUM].POWER=PON}
			ACTIVE(RESPONSE='PWSTANDBY'):{TUNER_STATE[TUNER_NUM].POWER=POFF}
			ACTIVE(FIND_STRING(RESPONSE,'ON',5)):{TUNER_STATE[TUNER_NUM].SLOT_STATE[SLOT_NUM].POWER=PON}
			ACTIVE(FIND_STRING(RESPONSE,'STANDBY',5)):{TUNER_STATE[TUNER_NUM].SLOT_STATE[SLOT_NUM].POWER=POFF}
		    }
		}
		CASE 'SI':	// Source select
		{
		    TUNER_STATE[TUNER_NUM].SOURCE=ATOI(RIGHT_STRING(RESPONSE,1))
		}
		CASE 'TU':	// Tuner type
		{
		    SWITCH(RIGHT_STRING(RESPONSE,2))
		    {
			CASE 'AN':{TUNER_STATE[TUNER_NUM].SLOT_STATE[SLOT_NUM].TYPE=AN}
			CASE 'XM':{TUNER_STATE[TUNER_NUM].SLOT_STATE[SLOT_NUM].TYPE=XM}
			CASE 'HD':{TUNER_STATE[TUNER_NUM].SLOT_STATE[SLOT_NUM].TYPE=HD}
			CASE 'DA':{TUNER_STATE[TUNER_NUM].SLOT_STATE[SLOT_NUM].TYPE=DA}
			CASE 'NO':{TUNER_STATE[TUNER_NUM].SLOT_STATE[SLOT_NUM].TYPE=NO}
		    }
		}
	    }
	}
    }
}