PANASONIC TH-50PH11UK && MIO-PRESTIGE S

playskool1

i am working with a Panasonic TH-50PH11UK LCD and a AMX MIO-PRESTIGE S keypad.

i am having trouble ramping up volume and ramping down volume. it is not repeating. also the feedback light on keypad buttons do not light up.

BUTTON_EVENT[dvKP_229,6]
{
	PUSH:
	{
		SEND_STRING dvLCD2,"$02,'AVL**',$03"					//LCD VOL +
	}
}
BUTTON_EVENT[dvKP_229,7]
{
	PUSH:
	{
                LCDmute = !LCDmute
		SEND_STRING dvLCD2,"$02,'AMT1',$03"					//LCD MUTE
	}
}
BUTTON_EVENT[dvKP_229,8]
{
	PUSH:
	{
		SEND_STRING dvLCD2,"$02,'AVL**',$03"			     	        //LCD VOL -
	}
}

JohnMichnr

The AMT** command for the display is a command to send a discrete volume level. you would have to send AMT00 thru AMT63 to set the volume to that level.

A volume up for the Panasonic is $02,'AUU',$03 that will ramp it up one point
volume down is $02,'AUD',$03

so one option would be:

button_event[dvKP_229,6]
{
  push:
  {
     to[button.input] //feedback
     send_string dvLCD2, "$02,'AUU',$03"
  }
}

if you want it to repeat - put in a hold statement

button_event[dvKP_229,6]
{
  push:
  {
     to[button.input] //feedback
     send_string dvLCD2, "$02,'AUU',$03"
  }
  hold[1,repeat]
  {
    send_string dvLCD2, "$02,'AUU',$03"
  }
}

I like to add one thing so that the button can be pushed once fora single pulse and held longer for multiple pulses:

button_event[dvKP_229,6]
{
  push:
  {
     to[button.input] //feedback
     send_string dvLCD2, "$02,'AUU',$03"
  }
  hold[1,repeat]:
  {
    if(button.holdtime>7) //hold the button longer than .7 seconds
      send_string dvLCD2, "$02,'AUU',$03"
  }
}

Ditto for the down

Jimweir192

playskool1 wrote: »

also the feedback light on keypad buttons do not light up.

You don't have any feedback commands, depending on how you want your feedback to occur there are many ways to code it, you could just add a TO[button.input] to each push

playskool1

Jimweir192 wrote: »

You don't have any feedback commands, depending on how you want your feedback to occur there are many ways to code it, you could just add a TO[button.input] to each push

got that down.

now my only issue is controlling the PANASONIC TH-50PH11UK. i checked the AMX NI-3100 and the TX and RX blink together so i know my RS232 control is working fine. is there something i am missing on my command/parameters? the only buttons on the MIO PRESTIGE S Keypad that work are buttons 3 & 4. Button 2, only the audio works but no video.

DEFINE_EVENT

BUTTON_EVENT[dvKP_203,1]
{
	PUSH:
	{
		TO[button.input] //FEEDBACK
		SEND_STRING dvLCD1,"$02,'PON',$03"					//TURN ON #203 LCD
	}
}
BUTTON_EVENT[dvKP_203,2]
{
	PUSH:
	{
		TO[button.input] //FEEDBACK
		SEND_STRING dvSWITCHER,"'CL0I1O2T'"					//RACK VCR
		SEND_STRING dvLCD1,"$02,'IMS:SL1B',$03"
	}
}
BUTTON_EVENT[dvKP_203,3]
{
	PUSH:
	{
		TO[button.input] //FEEDBACK
		SEND_STRING dvSWITCHER,"'CL0I7O2T'"					//#203 WALL PLATE VGA
		SEND_STRING dvLCD1,"$02,'IMS:PC1',$03"
	}
}
BUTTON_EVENT[dvKP_203,4]
{
	PUSH:
	{
		TO[button.input] //FEEDBACK
		SEND_STRING dvSWITCHER,"'CL0I4O2T'"					//#203 RACK PC2
		SEND_STRING dvLCD1,"$02,'IMS:PC1',$03"
	}
}
BUTTON_EVENT[dvKP_203,5]
{
	PUSH:
	{
		TO[button.input] //FEEDBACK
		SEND_STRING dvLCD1,"$02,'POF',$03"					//TURN OFF #203 LCD
	}
}
BUTTON_EVENT[dvKP_203,6]
{
  PUSH:
  {
     TO[button.input] //FEEDBACK
     SEND_STRING dvLCD1, "$02,'AUU',$03"
  }
  HOLD[1,REPEAT]:
  {
    IF(button.holdtime>7)                                    //HOLD .7 SECONDS
      SEND_STRING dvLCD1, "$02,'AUU',$03"
  }
}
BUTTON_EVENT[dvKP_203,7]
{
	PUSH:
	{
		TO[button.input] //FEEDBACK
		SEND_STRING dvLCD1,"$02,'AMT1',$03"					//LOCAL MUTE
	}
}
BUTTON_EVENT[dvKP_203,8]
{
  PUSH:
  {
     TO[button.input] //FEEDBACK
     SEND_STRING dvLCD1, "$02,'AUD',$03"
  }
  HOLD[1,REPEAT]:
  {
    IF(button.holdtime>7)                                    //HOLD .7 SECONDS
      SEND_STRING dvLCD1, "$02,'AUD',$03"
  }
}

playskool1

PANASONIC TH-50PH11UK

i think i figured out the mute toggle using both parameters.

BUTTON_EVENT[dvKP_203,7]
{
	PUSH:
	{
		TO[button.input] //FEEDBACK
		IF(nLCD1Mute = 0)
{
      SEND_STRING dvLCD1,"$02,'AMT1',$03"		//Mute ON
      nLCD1Mute = 1
}
ELSE
{
      SEND_STRING dvLCD1,"$02,'AMT0',$03"		//Mute OFF
      nLCD1Mute = 0
}
	}
}

playskool1

doh! fixed. i forgot the Data_Event.