ASTRO_CLOCK vs. TimeManager, sunrise/set

DEFINE_DEVICE
dvDEBUG								=	0:0:2
dvMASTER								=	0:1:2
vdvTP										= 33002:1:2
dvTMTIMESYNC						=	0:3:2
vdvTMEVENTS						=	33001:1:2

//******************************************************************************
//	CONSTANT DEFINITIONS
//******************************************************************************
DEFINE_CONSTANT
// TIME SERVER CONSTANTS
(* TIMESERVER PROTOCOLS *)
nProtoNone        		= 0
nProtoDaytime     		= 1
nProtoTime        		= 2
nProtoSNTP        		= 3
nProtoSNTPBCast   		= 4

(* TIME SERVER CHANNELS *)
nTmSunriseChannel     = 1
nTmSunsetChannel      = 2
nTmDstChannel         = 3
nTmTimeChangeChannel  = 4

(* TIME SERVER LEVELS *)
nTmGmtEffLevel        = 1
nTmGmtLevel           = 2
nTmLongLevel          = 3
nTmLatLevel           = 4

//******************************************************************************
//	DATA TYPE DEFINITIONS
//******************************************************************************
DEFINE_TYPE

//******************************************************************************
//	VARIABLE DEFINITIONS
//******************************************************************************
DEFINE_VARIABLE
// TIME SERVER & TIME RELATED VARIABLES
//VOLATILE CHAR 				cTIMESTRSUNRISE[50]
//VOLATILE CHAR 				cTIMESTRSUNSET[50]
//VOLATILE SINTEGER 	sSUNRISEHOUR
//VOLATILE SINTEGER 	sSUNSETHOUR
//VOLATILE SINTEGER 	sSUNRISEMINUTE
//VOLATILE SINTEGER 	sSUNSETMINUTE
VOLATILE CHAR 				cTMSUNRISE[10]
VOLATILE CHAR 				cTMSUNSET[10]

(* TIMEZONE *)
VOLATILE CHAR    		cTMTZNAME[100]
VOLATILE CHAR    		cTMTZDESC[10]
VOLATILE DOUBLE  		dTMTZGMTOFFSET
VOLATILE CHAR    		cTMTZDSTRULES[1000]

(* LOCATION *)
VOLATILE CHAR    		cTMLOCNAME[100]
VOLATILE DOUBLE  		dTMLOCLONG
VOLATILE DOUBLE  		dTMLOCLAT

(* TIMESERVER *)
VOLATILE INTEGER 		nTMTSPROTOCOL
VOLATILE INTEGER 		nTMTSCHECKTIME
VOLATILE CHAR				cTMTSSERVER[100]

CLKMGR_TIMESERVER_STRUCT TS									// TO HOLD CURRENT TIMESERVER INFO
CLKMGR_TIMEOFFSET_STRUCT DST_OFFSET

VOLATILE CHAR				cDST_START_RULE[35]
VOLATILE CHAR				cDST_END_RULE[35]
VOLATILE INTEGER		nRESYNCH_PERIOD						// MINUTES
VOLATILE INTEGER		bDST_ON

VOLATILE SINTEGER		sRET_CODE
VOLATILE CHAR				cTZ_STRING[25]
VOLATILE DOUBLE			dHRS_TO_UTC								// CURRENT HRS FROM GMT OR UTC

CONSTANT LONG				lONE_MIN_TL		=	1					// TL ID
VOLATILE LONG				ONE_MIN[]			= {60000}		// 60,000/1,000 = 60 SEC
VOLATILE INTEGER 		nTL_RET										// TIMELINE_CREATE RETURN VALUE
VOLATILE DOUBLE 		dLATITUDE			=   47.6350	// NORTH LATITUDE FOR OLIN PLACE
VOLATILE DOUBLE 		dLONGITUDE		= -122.3129	// WEST LONGITUDE FOR OLIN PLACE
VOLATILE CHAR 				cSUNRISE[10]
VOLATILE CHAR 				cSUNSET[10]

//******************************************************************************
//	INCLUDE FILES
//******************************************************************************

//******************************************************************************
//	LATCHING DEFINITIONS
//******************************************************************************
DEFINE_LATCHING

//******************************************************************************
//	MUTUALLY EXCLUSIVE DEFINITIONS
//******************************************************************************
DEFINE_MUTUALLY_EXCLUSIVE

//******************************************************************************
//	SUBROUTINE AND FUNCTION DEFINITIONS
//******************************************************************************

//******************************************************************************
//	STARTUP
//******************************************************************************
DEFINE_START
(***********************************************************)
(* STEP 1 - CONFIGURE THE TIMEZONE:                        *)
(***********************************************************)

// CONFIGURE TIMEZONE
// PARAMETER 1: TIMEZONE NAME.  EX: "EASTERN"
// PARAMETER 2: TIMEZONE DESCRIPTION.  EX: "E%ST"
// PARAMETER 3: TIMEZONE GMT OFFSET IN HOURS.  EX: -5.0
cTMTZNAME					= 'Pacific'
cTMTZDESC					= 'PD%sT'
dTMTZGMTOFFSET		= -8.0

// CONFIGURE TIMEZONE RULES
// PARAMETER 1: DAYLIGHT SAVINGS STRING.  EX: "NONE", "US" OR CUSTOM.
// CUSTOM STRING: "MONTH" "DAYDESCRIPTION" "TIME" "OFFSET FROM STD" "DESCRPTION"
//                "MONTH":          MONTH NAME EX: "APR"
//                "TIME"            TIME TO ACTIVATE (HH:MM:SS, 24 HOUR).  EX: "02:00:00"
//                "OFFSET FROM STD" TIME TO OFFSET FROM GMT (HH:MM:SS, 24 HOUR).  EX: "01:00:00"
//                "DESCRIPTION"     STRING TO REPLACE "%S" WITH IN TIMEZONE DESCRIPTION.  EX: 'D'
//                "DAYDESCRIPTION"  DAY DESCRIPTION. FIXED DATE, LAST DAY OF WEEK OR
//                                  FIRST DAY OF WEEK BEFORE/AFTER DATE
//                                  FIXED EX: "15"
//                                  LAST DAY OF WEEK EX: "LASTSUNDAY"
//                                  FIRST DAY OF WEEK BEFORER DATE-EX: "SUN<=24"
//                                  FIRST DAY OF WEEK AFTER DATE-EX: "SUN>=1"
cTMTZDSTRULES 		= 'US'

(***********************************************************)
(* STEP 2 - CONFIGURE PHYSICAL LOCATION:                   *)
(***********************************************************)

// CONFIGURE PHYSICAL LOCATION
// PARAMETER 1: LOCATION NAME.  EX: 'SEATTLE'
// PARAMETER 2: LOCATION LONGITUDE.  EX: -122.33 (>0 == EAST, < 0 == WEST)
// PARAMETER 3: LOCATION LATITUDE.  EX: 47.6 (>0 == NORTH, < 0 == SOUTH)
cTMLOCNAME   			= 'Seattle'
dTMLOCLONG 				= -122.3129 
dTMLOCLAT 				=   47.6350

(***********************************************************)
(* STEP 3 - CONFIGURE TIME SERVERS:                        *)
(***********************************************************)

// CONFIGURE TIME SERVERS
// PARAMETER 1: PROTOCOL, 0=DISBALED, 1=DAYTIME(13/UDP, 13/TCP), 2=TIME(37/UDP, 37/TCP), 3=SNTP(123/UDP), 4=SNTP BROADCAST (137/UDP).  EX: 2
// PARAMETER 3: DEFAULT SERVER.  EX: 'MYTIMESERVER.MYDOMAIN.COM'.  LEAVE BLANK TO READ FROM TIME SEVRER FILE (TIME/NIST_SVR.LST)
// PARAMETER 2: CHECK TIME INTERVAL IN SECONDS.  USE 0 FOR DEFAULT (2 HOURS).  EX: 3600
// PARAMETER 4: PREFERED INDEX OF TIMESERVERS IN LIST.  EX: 2
// NOTES:       IF PARAMETERS 3 IS SUPPLIED, PARAMETER 4 IS IGNORED
//              IF PARAMATER 3 IS AN EMPTY STRING AND PARAMETER 4 IS 0, A DEFAULT WILL BE PICKED FROM THE LIST IS POSSIBLE
// CONSTANTS-
//	nProtoNone       = 0
//	nProtoDaytime    = 1
//	nProtoTime       = 2
//	nProtoSNTP       = 3
//	nProtoSNTPBCast  = 4

nTMTSPROTOCOL   	= nProtoSNTP
nTMTSCHECKTIME  	= 0
cTMTSSERVER   		= ''

(***********************************************************)
(* ALTERNATE MANUAL TIMEZONE CONFIGURATIONS:               *)
(***********************************************************)

// THESE ARE SHOWN FOR EXAMPLE PURPOSES AND REPRESENT INFORMATION THAT IS NOT GUARANTEED TO BE CORRECT!

// HERE IS AN EXMAPLE CONFIGURATION FOR SANTIAGO, CHILE WHICH IS -4 HOURS BEHIND GMT AND OBSERVES DAYLIGHT SAVINGS STARTING
// ON THE SATURDAY ON OR AFTER OCTOBER 9TH AT MIDNIGHT (JUMP AHEAD 1 HOUR) AND THE SATURDAY ON OR AFTER THE 9TH OF MARCH AT MIDNIGHT (JUMP BACK 1 HOUR)
// AND DESCRIBES THE TIME AS "HH:MM:SS CST" OR "HH:MM:SS CDT" DEPENDING ON DAYLIGHT SAVINGS AND IS LOCATED AT "33S27, 70W40":
//
//		cTMTZNAME				= 'Santiago'
//		cTMTZDESC				= 'C%sT'
//		dTMTZGMTOFFSET	= -4.0
//		cTMTZDSTRULES		= "'Oct Sat>=9 00:00:00 01:00:00 D',$FF,'Mar Sat>=9 00:00:00 00:00:00 S'"
//
// AND
//
//		cTMLOCNAME			= 'Santiago'
//		dTMLOCLONG			= -70.67
//		dTMLOCLAT				= -33.45

// HERE IS AN EXMAPLE CONFIGURATION FOR SYDNEY, AUSTRALIA WHICH IS +10 HOURS AHEAD OF GMT AND OBSERVES DAYLIGHT SAVINGS STARTING
// ON THE LAST SUNDAY IN OCTOBER 2:00 AM (JUMP AHEAD 1 HOUR) AND THE LAST SUNDAY IN MARCH AT 3:00 AM (JUMP BACK 1 HOUR)
// AND DESCRIBES THE TIME AS "HH:MM:SS EST" REGARDLESS OF DAYLIGHT SAVINGS AND IS LOCATED AT "33S52, 151E13":
//
//		cTMTZNAME				= 'Sydney'
//		cTMTZDESC				= 'EST'
//		dTMTZGMTOFFSET	= 10.0
//		cTMTZDSTRULES		= "'Oct LastSun 02:00:00 01:00:00 X',$FF,'Mar LastSun 03:00:00 00:00:00 X'"
//
// AND
//
//		cTMLOCNAME			= 'Sydney'
//		dTMLOCLONG			= 151.22
//		dTMLOCLAT				= -33.86

// HERE IS THE EXAMPLE CONFIGURATION FOR LONDON, ENGLAND WHICH USES GMT AND OBSERVES DAYLIGHT SAVINGS STARTING
// ON THE LAST SUNDAY IN MARCH AT 1:00 AM (JUMP AHEAD 1 HOUR) AND THE LAST SUNDAY IN OCTOBER AT 2:00 AM (JUMP BACK 1 HOUR)
// AND DESCRIBES THE TIME AS "HH:MM:SS BST" OR "HH:MM:SS GMT" DEPENDING ON DAYLIGHT SAVINGS AND IS LOCATED AT "51N30, 0W10":
//
//		cTMTZNAME				= 'London'
//		cTMTZDESC				= '%s'
//		dTMTZGMTOFFSET	= 0.0
//		cTMTZDSTRULES		= "'Mar LastSun 01:00:00 01:00:00 BST',$FF,'Oct LastSun 02:00:00 00:00:00 GMT'"
//
// AND
//
//		cTMLOCNAME			= 'London'
//		dTMLOCLONG			= -0.16
//		dTMLOCLAT				= 51.50

// TIMELINES....
nTL_RET = TIMELINE_CREATE(lONE_MIN_TL,ONE_MIN,LENGTH_ARRAY(ONE_MIN),TIMELINE_ABSOLUTE,TIMELINE_REPEAT)

SWITCH(nTL_RET)
{
	CASE 0:
	{
		SEND_STRING dvDEBUG,"'TL lONE_MIN_TL SUCCESSFULLY STARTED.',$0D"
	}
	
	CASE 1:
	{
		SEND_STRING dvDEBUG,"'TIMELINE_CREATE: TIMELINE ID ALREADY IN USE.',$0D"
	}
	
	CASE 2:
	{
		SEND_STRING dvDEBUG,"'TIMELINE_CREATE: TIME ARARY NOT ARRAY OF LONGS.',$0D"	
	}
	
	CASE 3:
	{
		SEND_STRING dvDEBUG,"'TIMELINE_CREATE: LENGTH SPECIFIED GREATER THAN LENGTH OF PASSED TIME ARRAY.',$0D"	
	}
	
	CASE 4:
	{
		SEND_STRING dvDEBUG,"'TIMELINE_CREATE: OUT OF MEMORY.',$0D"	
	}
}	// END OF SWITCH ON TIMELINE RETURN
	
DEFINE_MODULE 'i!-TimeManagerMod' mdlTM(vdvTMEVENTS,
                                        dvTMTIMESYNC,
                                        (* TIMEZONE *)
                                        cTMTZNAME,
                                        cTMTZDESC,
                                        dTMTZGMTOFFSET,
                                        cTMTZDSTRULES,
                                        (* LOCATION *)
                                        cTMLOCNAME,
                                        dTMLOCLONG,
                                        dTMLOCLAT,
                                        (* TIMESERVER *)      
                                        nTMTSPROTOCOL,
                                        nTMTSCHECKTIME,
                                        cTMTSSERVER)

//******************************************************************************
//	EVENTS
//******************************************************************************
DEFINE_EVENT

TIMELINE_EVENT[lONE_MIN_TL]
{	
	cTZ_STRING = CLKMGR_GET_TIMEZONE()
	SEND_STRING dvDEBUG,"$0A,$0A,$0A,$0A,$0A,$0A,$0A,$0A"	// PUT SOME SPACE BETWEEN REPORTS
	SEND_STRING dvDEBUG,"'CLKMGR CURRENT TIMEZONE IS: ',cTZ_STRING,$0D"

	IF(FIND_STRING(cTZ_STRING,'UTC',1))
	{
		REMOVE_STRING(cTZ_STRING,'UTC',1)
		cTZ_STRING = LEFT_STRING(cTZ_STRING,(FIND_STRING(cTZ_STRING,':',1))-1)
		SEND_STRING dvDEBUG,"'CLKMGR cTZ_STRING= ',cTZ_STRING,$0D"
	}
	ELSE
		SEND_STRING dvDEBUG,"'UTC NOT FOUND IN CLKMGR cTZ_STRING!',$0D"
	
	IF(bDST_ON)
		dHRS_TO_UTC = -7.0
	ELSE
		dHRS_TO_UTC = -8.0
	
	sRET_CODE = ASTRO_CLOCK(dLONGITUDE,dLATITUDE,dHRS_TO_UTC,DATE,cSUNRISE,cSUNSET)
	
	SWITCH(sRET_CODE)
	{
		CASE 0:	{ SEND_STRING dvDEBUG,"'ASTRO_CLOCK FUNCTION EXECUTED OK',$0D"	}
		CASE 1:	{ SEND_STRING dvDEBUG,"'ASTRO_CLOCK LATITUDE ENTRY ERROR',$0D"	}
		CASE 2:	{ SEND_STRING dvDEBUG,"'ASTRO_CLOCK LONGITUDE ENTRY ERROR',$0D"	}
		CASE 3:	{ SEND_STRING dvDEBUG,"'ASTRO_CLOCK HOURS ENTRY ERROR',$0D"			}
		CASE 4:	{ SEND_STRING dvDEBUG,"'ASTRO_CLOCK DATE ENTRY ERROR',$0D"			}
	}	// END OF SWITCH ON RETURN CODE
	
	
	IF(CLKMGR_IS_NETWORK_SOURCED())
		SEND_STRING dvDEBUG,"'CLOCK MANAGER IS NETWORKED SOURCED',$0D"
	ELSE
		SEND_STRING dvDEBUG,"'CLOCK MANAGER IS STAND ALONE',$0D"
			
	CLKMGR_GET_ACTIVE_TIMESERVER(TS)
	CLKMGR_GET_DAYLIGHTSAVINGS_OFFSET(DST_OFFSET)
	cDST_START_RULE = CLKMGR_GET_START_DAYLIGHTSAVINGS_RULE()
	cDST_END_RULE = CLKMGR_GET_END_DAYLIGHTSAVINGS_RULE()
	nRESYNCH_PERIOD = CLKMGR_GET_RESYNC_PERIOD()
	bDST_ON = CLKMGR_IS_DAYLIGHTSAVINGS_ON()
	
	IF(TS.IS_SELECTED)
		SEND_STRING dvDEBUG,"TS.URL_STRING,', ',TS.LOCATION_STRING,' IS CURRENTLY SELECTED TIMESERVER.',$0D"
	ELSE
		SEND_STRING dvDEBUG,"'CLKMGR TIMESERVER IS NOT CURRENTLY SELECTED',$0D"
		
	
	
	SEND_STRING dvDEBUG,"'CURRENT TIME IS ',TIME,$0D"
	SEND_STRING dvDEBUG,"'DATE IS ',DATE,$0D"
	SEND_STRING dvDEBUG,"'SUNRISE TODAY AT ',cSUNRISE,$0D"
	SEND_STRING dvDEBUG,"'SUNSET TODAY AT ',cSUNSET,$0D"

}	// END OF TIMELINE_EVENT[lONE_MIN_TL]

DATA_EVENT[vdvTMEVENTS]
(***********************************************************)
(* DATA_EVENT:   STRINGS FOR SUNRISE/SUNSET                *)
(* PURPOSE:      PARSE STRINGS FOR SUNRISE AND SUNSET      *)
(***********************************************************)
{
  STRING:
  {
    STACK_VAR CHAR cUPPER[30]
    STACK_VAR CHAR cTEMP[30]
    STACK_VAR CHAR cTRASH[30]
    
    cUPPER = UPPER_STRING(DATA.TEXT)
    cTEMP = DATA.TEXT
    cTRASH = REMOVE_STRING(cTEMP,'-',1)
		
    SELECT
    {
      ACTIVE (FIND_STRING(cUPPER,'SUNRISE-',1)): 
      {
        SEND_STRING dvDEBUG,"'i!TimeManager Sunrise Time = ',cTEMP" 
        cTMSUNRISE = cTEMP
      }
        
      ACTIVE (FIND_STRING(cUPPER,'SUNSET-',1)):
      {
        SEND_STRING dvDEBUG,"'i!TimeManager Sunset Time = ',cTEMP" 
        cTMSUNSET = cTEMP
      }
				
      ACTIVE (FIND_STRING(cUPPER,'TIMEZONE-',1)):
			{
        SEND_STRING dvDEBUG,"'i!TimeManager Timezone = ',cTEMP"
			}
				
      ACTIVE (FIND_STRING(cUPPER,'TIMEDESC-',1)):
			{
        SEND_STRING dvDEBUG,"'i!TimeManager Time Description = ',cTEMP"
      }
			
      ACTIVE (FIND_STRING(cUPPER,'LOCATION-',1)):
			{
        SEND_STRING dvDEBUG,"'i!TimeManager: Location = ',cTEMP"
			}
    }	// END OF SELECT-ACTIVE
  }	// END OF STRING DATA_EVENT
}	// END OF vdvTMEVENTS DATA_EVENT

BUTTON_EVENT[vdvTMEVENTS,nTmSunriseChannel]
(***********************************************************)
(* BUTTON_EVENT: SUNRISE CHANNEL                           *)
(* PURPOSE:      CHANNEL IS PUSHED (AND TURNED ON) WHEN    *)
(*               THE SUNRISE OCCURS                        *)
(***********************************************************)
{
  PUSH:
  {
    SEND_STRING dvDEBUG,"'i!TimeManager: Sunrise occured at ',TIME"
  }
}

BUTTON_EVENT[vdvTMEVENTS,nTmSunsetChannel]
(***********************************************************)
(* BUTTON_EVENT: SUNSET CHANNEL                            *)
(* PURPOSE:      CHANNEL IS PUSHED (AND TURNED ON) WHEN    *)
(*               THE SUNSET OCCURS                         *)
(***********************************************************)
{
  PUSH:
  {
    SEND_STRING dvDEBUG,"'i!TimeManager: Sunset occured at ',TIME"
  }
}

BUTTON_EVENT[vdvTMEVENTS,nTmDstChannel]
(***********************************************************)
(* BUTTON_EVENT: DST ACTIVITY CHANNEL                      *)
(* PURPOSE:      CHANNEL IS PUSHED (AND TURNED ON) WHEN    *)
(*               THE DST RULES AFFECT A TIME CHANGE WITH   *)
(*               A NON-ZERO TIME OFFSET (DST ACTIVE)       *)
(*               CHANNEL IS RELEASE (AND TURNED OFF) WHEN  *)
(*               THE DST RULES AFFECT A TIME CHANGE WITH   *)
(*               A ZERO TIME OFFSET (DST INACTIVE)         *)
(***********************************************************)
{
  PUSH:
  {
    SEND_STRING dvDEBUG,"'i!TimeManager: DST is now active: ',TIME"
  }
  RELEASE:
  {
    SEND_STRING dvDEBUG,"'i!TimeManager: DST is now inactive: ',TIME"
  }
}

BUTTON_EVENT[vdvTMEVENTS,nTmTimeChangeChannel]
(***********************************************************)
(* BUTTON_EVENT: TIME CHANGE CHANNEL                       *)
(* PURPOSE:      CHANNEL IS PUSHED (AND PULSED) WHEN       *)
(*               THE TIME IS CHANGED BY A COMMUNICATION    *)
(*               WITH A TIME SERVER.                       *)
(***********************************************************)
{
  PUSH:
  {
    SEND_STRING dvDEBUG,"'i!TimeManager: Time adjusted by time server.  New Time is ',TIME"
  }
}

LEVEL_EVENT[vdvTMEVENTS,nTmGmtEffLevel]
(***********************************************************)
(* LEVEL_EVENT:  EFFECTIVE GMT OFFSET                      *)
(* PURPOSE:      LEVEL IS SENT WHENEVER THE EFFECTIVE GMT  *)
(*               OFFSET IS CHANGED.  THE EFFECTIVE OFFSET  *)
(*               IS THE REAL GMT OFFSET WITH DLS CORRECTION*)
(***********************************************************)
{
  SEND_STRING dvDEBUG,"'i!TimeManager: Effective GMT Offset = ',FTOA(LEVEL.VALUE)"
}

LEVEL_EVENT[vdvTMEVENTS,nTmGmtLevel]
(***********************************************************)
(* LEVEL_EVENT:  GMT OFFSET                                *)
(* PURPOSE:      LEVEL IS SENT WHENEVER THE GMT            *)
(*               OFFSET IS CHANGED.                        *)
(***********************************************************)
{
  SEND_STRING dvDEBUG,"'i!TimeManager: GMT Offset = ',FTOA(LEVEL.VALUE)"
}

LEVEL_EVENT[vdvTMEVENTS,nTmLongLevel]
(***********************************************************)
(* LEVEL_EVENT:  LONGITUDE                                 *)
(* PURPOSE:      LEVEL IS SENT WHENEVER THE LONGITUDE IS   *)
(*               CHANGED.                                  *)
(***********************************************************)
{
  SEND_STRING dvDEBUG,"'i!TimeManager: Longitude = ',FTOA(LEVEL.VALUE)"
}

LEVEL_EVENT[vdvTMEVENTS,nTmLatLevel]
(***********************************************************)
(* LEVEL_EVENT:  LATITUDE                                  *)
(* PURPOSE:      LEVEL IS SENT WHENEVER THE LATITUDE IS    *)
(*               CHANGED.                                  *)
(***********************************************************)
{
  SEND_STRING dvDEBUG,"'i!TimeManager: Latitude = ',FTOA(LEVEL.VALUE)"
}

//******************************************************************************
//	MAINLINE PROGRAM
//******************************************************************************
DEFINE_PROGRAM

//******************************************************************************
//	END
//******************************************************************************
//******************************************************************************